The previous programs which must be previously processed prior to this are tzabal and tzamap.
$title A CGE Model of the Impact of AGOA Policy on Tanzania
SET s List of activities and commodities/
MAIZE Growing of maize,
PADDY Growing of paddy,
SORGH Growing of sorghum and millet,
WHEAT Growing of wheat,
BEANS Growing of beans,
CASSA Growing of cassave,
CEREA Growing of other cereals,
OILSE Growing of oil seeds,
ROOTS Growing of other roots and tubers,
COTTO Growing of cotton,
COFFE Growing of coffee,
TOBAC Growing of Tobaco,
TEAGR Growing of tea,
CASHE Growing of cashew nuts,
SISAL Growing of sisal fiber,
SUGAR Growing of sugar cane ,
OFRVE Growing of fruits and vegetables,
OCROP Growing of other crops,
LIVES Operation of poultry and livestock,
FISHI Fishing and fish farms,
HUFOR Hunting and forestry,
MININ Mining and quarying,
MEATD Processing of meat and dairy products,
GRAIN Grain milling,
PFOOD Processed food,
BEVER Beverage and tobacco products,
CLOTH Textile and leather products,
WOODP Wood paper printing,
CHEMI Manufacrure of basic and industrial chemicals,
FERTI Manufacturer of fertilizer and pesticides,
PETRO Petroleum refinaries,
RUPLA Rubber plastic and other manufacturing,
GLASS Glass and cement,
METAL Iron steel and metal products,
EQUIP Manufacture all equipment,
UTILI Utilities,
CONST Construction,
TRADE Wholesale and retail trade'
HOTEL Hotels and restaurant,
TRANS Transport and communication,
ESTAT Real estate,
ADMIN Public administration health and education,
PRIVS Business and other services /,
M Margins /
CTDTP-E Export transactions costs,
CTDTP-D Domestic sales transactions costs,
CTDTP-M Import transactions costs /,
F Factors of production /
FSUB Subsistence factor,
LCHILD Child labor age 10 to 14,
LNONF Female laboe with no formal education,
LNFPF Female labor nonfinished primary school,
LNFSF Female labor nonfinished secondary school,
LSECF Female labor secondary or higher education,
LNONM Male laboe with no formal education,
LNFPM Male labor nonfinished primary school,
LNFSM Male labor nonfinished secondary school,
LSECM Male labor secondary or higher education,
CAPAG Agricultural capital,
CAPNAG Non-agricultural capital,
LAND Agricultural land /,
H Household Groups /
HRBFPL Rural below food poverty line,
HRFBPL Rural between basic needs poverty line,
HRNOED Rural nonpoor head with non education,
HRNFPS Rural nonpoor head not finished primary school,
HRNFSS Rural nonpoor head not finished secondary school,
HRSECP Rural nonpoor head finished secondary school,
HUBFPL Urban below food poverty line,
HUFBPL Urban between basic needs poverty line,
HUNOED Urban nonpoor head with non education,
HUNFPS Urban nonpoor head not finished primary school,
HUNFSS Urban nonpoor head not finished secondary school,
HUSECP Urban nonpoor head finished secondary school/ ,
T Taxes /
DIRTAX Direct taxes on domestic products,
IMPTAX Import tariff,
EXPTAX Export taxes,
VATAX Value added or activity taxes,
INDTAX Indirect or sales taxes,
FACTAX Factor taxes /;
alias (g,s);
parameter
ca(g,s) Intermediate inputs demand,
fa(f,s) Factor demand or value added,
ta(t,s) Tax collection,
ha(s,h) Household consumption of own production,
ac(s,g) Marketed output
mc(m,g) Marketing and transportation costs
tc(t,g) Indirect taxes
rc(g) Value of imports at (cif)
cm(g,m) Wholesale and retail cost
gd(g) Government Demand
er(g) Export (fob),
cs(g) Private investiment demand,
ch(g,h) Private consumption,
hf(h,f) Factor income to households
ef(f) Factor income to enterprise
gf(f) Factor income to government
tf(t,f) Factor taxes to government
rf(f) Factor remitance to rest of RoW
dp(f) Depreciation,
tp(t,h) Income tax payment by households,
he(h) Enterprise payment to households,
hg(h) Government transfer to households,
hr(h) Household income from RoW,
psv(h) Private savings,
te(t) Enterprise direct taxes,
ge Enterprise dividend payment to government,
gsv Government savings
fsv Foreign savings,
tr(t) Tax revenue;
* Read the data from the tzamap program:
$gdxin 'tzamap.gdx'
$load ca fa ta ha ac mc tc rc cm gd er cs ch hf ef gf tf rf dp tp he hg hr psv te ge gsv fsv tr
parameter t_y(s) Value-added taxes (here levied as a tax on output),
py0(s) Output price
ya(g) Aggregate output from all sectors
as(g) Aggregate supply
t_m(g) Import tariff rate
pm0(g) Reference import price
t_i(g) Indirect tax rate,
ex(g) Exports at producer prices
dm(g) Domestic use
xi(g) Adjustment to account for negative implicit supply;
t_y(s) = sum(t, ta(t,s)) / sum(g, ac(s,g));
py0(s) = 1 - t_y(s);
ex(g) = er(g) - mc("CTDTP-E",g);
ya(g) = max(sum(s, ac(s,g)), ex(g));
xi(g) = ya(g) - sum(s, ac(s,g));
display xi;
dm(g) = ya(g) - ex(g);
as(g) = rc(g) + sum(t, tc(t,g)) + mc("ctdtp-d",g) + mc("ctdtp-m",g) + dm(g);
t_m(g)$rc(g) = tc("imptax",g) / rc(g);
pm0(g) = 1 + t_m(g);
t_i(g)$as(g) = tc("indtax",g) / as(g);
parameter chk;
chk(g,"ya") = ya(g);
chk(g,"ex") = ex(g);
chk(g,"ya-ex") = ya(g) - ex(g);
display chk, dm, cm;
$ontext
$model:AGOA
$sectors:
x(g) ! Allocation of output to domestic and export markets
y(s) ! Sectoral output (domestic production)
e(g)$er(g) ! Export activity (applies margins)
a(s) ! Aggregate supply (Armington aggregate)
mg ! Transport margins
c(h) ! Household consumption
invest ! Aggregate investment
$commodities:
py(g) ! Output price
pd(g)$dm(g) ! Domestic sales price
px(g)$ex(g) ! Export price
pa(g) ! Composite demand price for marketed ouput
pc(h) ! Household consumption price
pt ! Trade and transport margins
pf(f) ! Factor prices
pg ! Lump-sum tax revenue
pe ! Enterprise rents
pfx ! Price of foreign exchange
pinv ! Investment
$consumers:
ra(h) ! Private households
govt ! Government
entr ! Private firms
* Production for domestict market and for export:
$prod:y(s) s:0 t:4 va:1
o:py(g) q:ac(s,g) a:govt t:t_y(s) p:py0(s)
o:pc(h) q:ha(s,h)
i:pa(g) q:ca(g,s)
i:pf(f) q:fa(f,s) va:
$prod:x(g) t:2
o:pd(g) q:(ya(g)-ex(g))
o:px(g) q:ex(g)
i:py(g) q:ya(g)
$prod:e(g)$er(g)
o:pfx q:er(g)
i:px(g) q:ex(g)
i:pt q:mc("CTDTP-E",g)
* Trade margins:
$prod:mg s:0
o:pt q:(sum((m,g), mc(m,g)))
i:pa(g) q:(sum(m,cm(g,m)))
* Armington aggregation of domestic and imported goods:
$prod:a(g) dm:2 d(dm):0 m(dm):0
o:pa(g) q:as(g) a:govt t:t_i(g)
i:pd(g) q:dm(g) d:
i:pt q:mc("CTDTP-D",g) d:
i:pfx q:rc(g) m: p:pm0(g) a:govt t:t_m(g)
i:pt q:mc("CTDTP-M",g) m:
* Investment:
$prod:invest
o:pinv q:(sum(g,cs(g)))
i:pa(g) q:cs(g)
* Total household consumption equals sums of private and own produced goods:
$prod:c(h) s:1
o:pc(h) q:(sum(g,ch(g,h)))
i:pa(g) q:ch(g,h)
* Household demand with exogenously fixed investment, taxes and transfers:
$demand:ra(h)
d:pc(h)
e:pinv q:(-psv(h))
e:pfx q:(hg(h)+hr(h)-sum(t,tp(t,h)))
e:pe q:he(h)
e:pf(f) q:hf(h,f)
$demand:entr
d:pe
e:pf(f) q:ef(f)
e:pfx q:(-sum(t,te(t)))
e:pa(g) q:(-gd(g))
e:pg q:(sum(g,gd(g)))
$demand:govt s:0
d:pg
e:py(g) q:xi(g)
e:pa(g) q:(-xi(g))
e:pinv q:(-gsv-fsv)
e:pe q:ge
e:pf(f) q:(gf(f)+rf(f)+sum(t,tf(t,f)))
e:pfx q:(sum(t, te(t))-sum(h,hg(h))+fsv-sum(f,rf(f))+sum((t,h),tp(t,h)))
$offtext
$sysinclude mpsgeset AGOA
AGOA.iterlim = 0;
$include AGOA.gen
solve AGOA using mcp;
* Simulation: decrease export transaction costs:
AGOA.iterlim = 10000;
parameter EV Welfare impact of removing transaction costs for export markets (% change);
parameter mce(g) Export margins (base year data)
ra0(h) Reference income level;
ra0(h) = ra.l(h);
mce(g) = mc("CTDTP-E",g);
* Examine the welfare impact of removing export margins on a
* commodity by commodity basis:
set greform(g); greform(g) = yes$(mce(g) gt 0);
loop(greform,
mc("CTDTP-E",greform) = 0;
$include AGOA.gen
Solve AGOA using mcp;
ev(h,greform) = round(100 * (ra.l(h)/(pc.l(h)*ra0(h)) - 1), 1);
mc("CTDTP-E",g) = mce(g);
);
option ev:1;
display ev;
parameter margins Transactions costs margins on a gross basis (%);
margins(g,"Export")$er(g) = 100 * mc("CTDTP-E",g)/er(g);
margins(g,"Domestic")$(mc("CTDTP-D",g)+dm(g)) = 100 * mc("CTDTP-D",g)/(mc("CTDTP-D",g)+dm(g));
margins(g,"iMport")$(mc("CTDTP-m",g)+rc(g)*pm0(g))
= 100 * mc("CTDTP-m",g)/(mc("CTDTP-m",g)+rc(g)*pm0(g));
option margins:1;
display margins;
---- 167 PARAMETER xi Adjustment to account for negative implicit supply
CASHE 1.000
---- 179 PARAMETER chk
ya ex ya-ex
MAIZE 411.000 1.000 410.000
PADDY 337.000 3.000 334.000
SORGH 62.000 62.000
WHEAT 25.000 25.000
BEANS 155.000 1.000 154.000
CASSA 47.000 47.000
CEREA 30.000 30.000
OILSE 93.000 3.000 90.000
ROOTS 68.000 68.000
COTTO 96.000 37.000 59.000
COFFE 84.000 84.000
TOBAC 75.000 42.000 33.000
TEAGR 39.000 23.000 16.000
CASHE 88.000 88.000
SISAL 17.000 17.000
SUGAR 158.000 12.000 146.000
OFRVE 348.000 25.000 323.000
OCROP 39.000 4.000 35.000
LIVES 247.000 6.000 241.000
FISHI 323.000 62.000 261.000
HUFOR 169.000 6.000 163.000
MININ 128.000 19.000 109.000
MEATD 246.000 1.000 245.000
GRAIN 648.000 7.000 641.000
PFOOD 410.000 7.000 403.000
BEVER 166.000 1.000 165.000
CLOTH 412.000 16.000 396.000
WOODP 147.000 6.000 141.000
CHEMI 66.000 3.000 63.000
FERTI 11.000 11.000
PETRO 27.000 27.000
RUPLA 54.000 1.000 53.000
GLASS 89.000 7.000 82.000
METAL 133.000 1.000 132.000
EQUIP 115.000 8.000 107.000
UTILI 216.000 216.000
CONST 770.000 770.000
TRADE 1013.000 1013.000
HOTEL 454.000 454.000
TRANS 685.000 579.000 106.000
ESTAT 1423.000 1423.000
ADMIN 1585.000 71.000 1514.000
PRIVS 402.000 142.000 260.000
---- 179 PARAMETER dm Domestic use
MAIZE 410.000, PADDY 334.000, SORGH 62.000, WHEAT 25.000, BEANS 154.000, CASSA 47.000, CEREA 30.000
OILSE 90.000, ROOTS 68.000, COTTO 59.000, TOBAC 33.000, TEAGR 16.000, SISAL 17.000, SUGAR 146.000
OFRVE 323.000, OCROP 35.000, LIVES 241.000, FISHI 261.000, HUFOR 163.000, MININ 109.000, MEATD 245.000
GRAIN 641.000, PFOOD 403.000, BEVER 165.000, CLOTH 396.000, WOODP 141.000, CHEMI 63.000, FERTI 11.000
PETRO 27.000, RUPLA 53.000, GLASS 82.000, METAL 132.000, EQUIP 107.000, UTILI 216.000, CONST 770.000
TRADE 1013.000, HOTEL 454.000, TRANS 106.000, ESTAT 1423.000, ADMIN 1514.000, PRIVS 260.000
---- 179 PARAMETER cm Wholesale and retail cost
CTDTP-E CTDTP-D CTDTP-M
TRADE 43.000 267.000 49.000
---- 1212 PARAMETER EV Welfare impact of removing transaction costs for export markets (% change)
OILSE COTTO COFFE TOBAC TEAGR CASHE SUGAR OFRVE FISHI MININ
HRBFPL -0.5 -0.4 -0.6 2.0 0.9 -0.7 -0.6 -0.5 -0.4 -0.6
HRFBPL -0.5 -0.3 -0.5 2.0 0.7 -0.7 -0.5 -0.4 -0.4 -0.5
HRNOED -0.4 -0.3 -0.4 1.3 -0.1 -0.5 -0.4 -0.3 -0.3 -0.4
HRNFPS -0.4 -0.2 -0.5 2.2 3.0 -0.5 -0.3 -0.3 -0.3 -0.4
HRNFSS 0.3 0.4 0.3 0.2 -0.3 0.2 0.3 0.3 0.3 0.3
HRSECP 0.5 0.4 0.7 -0.1 0.4 0.5 0.4 0.4 0.5
HUBFPL 0.6 0.6 0.6 -1.2 0.3 0.5 0.6 0.5 0.6 0.6
HUFBPL 1.1 1.0 1.3 -2.3 0.4 1.1 1.1 1.1 1.0 1.2
HUNOED 1.1 0.9 1.2 -2.6 -0.4 1.0 1.1 1.0 1.0 1.1
HUNFPS 0.7 0.7 0.6 -0.8 3.8 0.6 0.8 0.6 0.7 0.7
HUNFSS 0.7 0.7 0.8 -0.6 -0.6 0.6 0.7 0.7 0.6 0.7
HUSECP -0.5 -0.5 -0.5 1.5 -0.6 -0.6 -0.5 -0.5 -0.5 -0.5
+ CLOTH
HRBFPL -0.6
HRFBPL -0.5
HRNOED -0.4
HRNFPS -0.4
HRNFSS 0.3
HRSECP 0.5
HUBFPL 0.6
HUFBPL 1.2
HUNOED 1.1
HUNFPS 0.7
HUNFSS 0.7
HUSECP -0.5
---- 1221 PARAMETER margins Transactions costs margins on a gross basis (%)
EXPORT DOMESTIC IMPORT
MAIZE 6.2 5.6
PADDY 5.9 3.8
SORGH 7.5
WHEAT 7.4 4.8
BEANS 5.5
CASSA 9.6
CEREA 6.2
OILSE 25.0 10.0
ROOTS 6.8
COTTO 11.9 9.2
COFFE 11.6
TOBAC 12.5 8.3
TEAGR 11.5 5.9
CASHE 6.4
SISAL 5.6
SUGAR 7.7 5.8 4.7
OFRVE 10.7 10.0 11.1
OCROP 5.4
LIVES 4.4
FISHI 4.6 4.4
HUFOR 4.7
MININ 5.0 4.4 6.2
MEATD 2.0
GRAIN 3.0 5.6
PFOOD 2.9 2.4
BEVER 9.3 10.0
CLOTH 5.9 3.4 3.3
WOODP 2.8 2.7
CHEMI 3.1 2.5
PETRO 3.6 3.9
RUPLA 1.9 1.5
GLASS 2.4
METAL 2.2 2.2
EQUIP 2.7 2.2